RGBA

• 来源: https://www.freebasic.net/wiki/wikka.php?wakka=KeyPgRgba
• 最后更新: 2021-10-13

---

计算包含 alpha（透明度）的高彩/真彩模式有效颜色值

语法

#define RGBA(r,g,b,a) CUlng((CUByte(r) shl 16) or (CUByte(g) shl 8) or CUByte(b) or (CUByte(a) shl 24))

用法

result = RGBA(red, green, blue, alpha)

参数

red

红色分量值

green

绿色分量值

blue

蓝色分量值

alpha

alpha 分量值

返回值

合并后的颜色值。

说明

red、green、blue 和 alpha 是范围 0-255 的分量。

RGBA 函数可用于计算包含 alpha 通道的高彩/真彩模式有效颜色值。它返回一个无符号长整数，格式为 &hAARRGGBB，其中 RR、GG、BB、AA 等于以十六进制格式传递给此函数的值。

可以使用 And 和 Shr 的组合从颜色值中检索红、绿、蓝和 alpha 值。下面的第二个示例展示了如何 #Define 和使用宏来实现这一点。

示例

start GeSHi

'open a graphics screen (320 * 240, 32-bit)
ScreenRes 320, 240, 32

Dim As Any Ptr img
Dim As Integer x, y

'make an image that varies in transparency and color
img = ImageCreate(64, 64)
For x = 0 To 63
  For y = 0 To 63
    PSet img, (x, y), RGBA(x * 4, 0, y * 4, (x + y) * 2)
  Next y
Next x
Circle img, (31, 31), 25,      RGBA(0, 127, 192, 192), ,,, F 'semi-transparent blue circle
Line   img, (26, 20)-(38, 44), RGBA(255, 255, 255, 0),    BF 'transparent white rectangle

'draw a background (diagonal white lines)
For x = -240 To 319 Step 10
  Line (x, 0)-Step(240, 240), RGB(255, 255, 255)
Next

Line (10,  10)-(310,  37), RGB(127, 0, 0), BF 'red box for text
Line (10, 146)-(310, 229), RGB(0, 127, 0), BF 'green box for Putting onto

'draw the image and some text with PSET
Draw String(64, 20), "PSet"
Put(48,  48), img, PSet
Put(48, 156), img, PSet

'draw the image and some text with ALPHA
Draw String (220, 20), "Alpha"
Put(208,  48), img, Alpha
Put(208, 156), img, Alpha

'Free the image memory
ImageDestroy img

'Keep the window open until the user presses a key
Sleep

end GeSHi

start GeSHi

'' setting and retrieving Red, Green, Blue and Alpha values

#define RGBA_R( c ) ( CULng( c ) Shr 16 And 255 )
#define RGBA_G( c ) ( CULng( c ) Shr  8 And 255 )
#define RGBA_B( c ) ( CULng( c )        And 255 )
#define RGBA_A( c ) ( CULng( c ) Shr 24         )

Dim As UByte r, g, b, a

Dim As ULong col = RGBA(255, 192, 64, 128)

Print Using "Color: _&H\      \"; Hex(col, 8)

r = RGBA_R( col )
g = RGBA_G( col )
b = RGBA_B( col )
a = RGBA_A( col )

Print
Print Using "Red:         _&H\\ = ###"; Hex(r, 2); r
Print Using "Green:       _&H\\ = ###"; Hex(g, 2); g
Print Using "Blue:        _&H\\ = ###"; Hex(b, 2); b
Print Using "Alpha:       _&H\\ = ###"; Hex(a, 2); a

end GeSHi

版本

• fbc 1.08.0 之前：

方言差异

• 在 -lang qb 方言中不可用，除非使用别名 __Rgba 引用。

与 QB 的区别

• FreeBASIC 新增

另请参阅

• RGB
• Color
• #Define

返回 目录